Escreva um programa Portugol para mover todos os zeros para o final do vetor, sem alterar a ordem dos elementos já presentes no array - Lista de Exercícios Resolvidos de Portugol

// vamos declarar e construir um vetor de 8 inteiros
inteiro valores[] = {0, 3, 0, 5, 7, 4, 0, 9}

Vetor na ordem original:

0   3   0   5   7   4   0   9   

Vetor com os zeros deslocados para o final:

3   5   7   4   9   0   0   0

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

programa 
{
  funcao inicio()
 {
    // vamos declarar e construir um vetor de 8 inteiros
    inteiro valores[] = {0, 3, 0, 5, 7, 4, 0, 9}
    inteiro j, temp

    // vamos mostrar o vetor na ordem original
    escreva("Vetor na ordem original:\n")
    para (inteiro i = 0; i < 8; i++) {
      escreva(valores[i] + "   ")
    }
    
    // vamos inicializar j como 0 para que ele aponte para
    // o primeiro elemento do vetor
    j = 0
    
    // agora o laço for percorre todos os elementos do vetor,
    // incrementanto a variável i e deixando o j em 0
    para (inteiro i = 0; i < 8; i++) {
      // encontramos um valor que não é 0
      se (valores[i] != 0) {
        // fazemos a troca entre os elementos nos índices
        // i e j
        temp = valores[i]
        valores[i] = valores[j]
        valores[j] = temp
        // e avançamos o j para o elemento seguinte
        j++
      }
    }
    
    // agora mostramos o resultado
    escreva("\n\nVetor com os zeros deslocados para o final:\n")
    para (inteiro i = 0; i < 8; i++) {
      escreva(valores[i] + "   ")
    }
    
    escreva("\n\n")
  }
}