Como acessar o AutoCAD a partir do Excel e retornar sua versão

----------------------------------------------------------------------
Precisa de ajuda? Chama no WhatsApp +55 (62) 98553-6711 (Osmar)

Este código foi útil? Doe R$ 5,00 e ajude-nos a manter o site no ar :-(
PIX: osmar@arquivodecodigos.com.br 
----------------------------------------------------------------------

' Não se esqueça de adicionar a referência ao
' AutoCAD 2021 Type Library
' Ferramentas -> Referências -> AutoCAD 2021 Type Library
' Mova esta referência o mais alto que puder usando as
' setas para cima e para baixo

Option Explicit

' vamos declarar a variável que representará a aplicação AutoCAD
Public acadApp As AcadApplication
' e uma variável para representar o documento do AutoCAD
Public acadDoc As AcadDocument

' corpo da macro que acessa o AutoCAD e retorna a sua versão
Sub AcessarAutoCAD()
  ' em caso de erro
  On Error Resume Next
         
  ' vamos obter a aplicação AutoCAD
  Set acadApp = Interaction.GetObject(, "AutoCAD.Application")
  ' poderia ser também
  ' Set acadApp = Interaction.GetObject(, "AutoCAD.Application.22")
     
  ' houve erro?
  If Err Then
    ' vai mostrar na janela de Verificação imediata
    Debug.Print "Erro: " & Err.Number
    Debug.Print Err.Description
    Debug.Print "Iniciando o AutoCAD"
    Err.Clear
                       
    ' criamos uma nova instância do objeto AcadApplication
    Set acadApp = New AcadApplication
    ' poderia ser também
    ' Set acadApp = Interaction.CreateObject("AutoCAD.Application.22")
         
    ' tornamos a aplicação visível na tela
    acadApp.Visible = True
         
    ' houve erro
    If Err Then
      MsgBox "Erro: " & Err.Description
      Exit Sub
    End If
  End If
     
  ' Se chegou até aqui, então deu tudo certo
  Debug.Print "Executando " + acadApp.Name + " versão " + acadApp.Version
          
  ' obtemos o documento ativo
  Set acadDoc = acadApp.ActiveDocument
  ' não existe documento aberto no AutoCAD?
  If acadDoc Is Nothing Then
    ' criamos um novo documento
    Set acadDoc = acadApp.Documents.Add
  End If
   
  ' não há espaço ativo?
  If acadDoc.ActiveSpace = 0 Then
    acadDoc.ActiveSpace = 1
  End If
End Sub