Informe um valor inteiro: 64
O número 64 é um quadrado perfeito
Informe um valor inteiro: 28
O número 28 não é um quadrado perfeito
Informe um valor inteiro: 16
O número 16 é um quadrado perfeito

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

algoritmo "Número quadrado perfeito em VisuAlg"

var
  // variáveis usadas na resolução do problema
  valor: inteiro

funcao testar_quadrado_perfeito(numero: inteiro): logico
var
  raiz_quadrada: real

inicio
  // primeiro calculamos a rais quadrada do número recebido
  raiz_quadrada <- RaizQ(numero)

  // agora testamos se a raiz quadrada do número menos o arredondamento
  // dele para baixo é igual a 0
  retorne ((raiz_quadrada - Int(raiz_quadrada)) = 0)
fimfuncao

inicio
  // vamos pedir para o usuário informar um valor inteiro
  escreva("Informe um valor inteiro: ")
  leia(valor)

  // vamos testar se o número informado é um quadrado perfeito
  se testar_quadrado_perfeito(valor) entao
    escreva("O número ", valor, " é um quadrado perfeito")
  senao
    escreva("O número ", valor, " não é um quadrado perfeito")
  fimse

fimalgoritmo

Informe a potência da lâmpada (em watts): 100
Informe a largura do cômodo (em metros): 6
Informe o comprimento do cômodo (em metros): 4
Serão necessárias 4 lâmpadas.

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

algoritmo "Como calcular o número de lâmpadas necessárias"

var
  // variáveis usadas na resolução do problema
  potencia_lampada, largura_comodo, comprimento_comodo: real
  area_comodo, potencia_total: real
  quant_lampadas: inteiro

inicio
  // vamos ler a potência da lâmpada
  escreva("Informe a potência da lâmpada (em watts): ")
  leia(potencia_lampada)

  // vamos ler a largura do cômodo
  escreva("Informe a largura do cômodo (em metros): ")
  leia(largura_comodo)

  // agora vamos ler o comprimento do cômodo
  escreva("Informe o comprimento do cômodo (em metros): ")
  leia(comprimento_comodo)

  // agora vamos calcular a área do cômodo
  area_comodo <- largura_comodo * comprimento_comodo

  // calculamos a potência total necessária para iluminar
  // todo o cômodo
  potencia_total <- area_comodo * 18

  // e finalmente calculamos a quantidade de lâmpadas necessárias
  quant_lampadas <- Int(potencia_total / potencia_lampada)

  // será necessário no mínimo uma lâmpada
  se quant_lampadas = 0 entao
    quant_lampadas <- quant_lampadas + 1
  fimse

  // e mostramos o resultado
  escreva("Serão necessárias ", quant_lampadas, " lâmpadas.")

fimalgoritmo

Informe o valor do produto: 520
Informe o nome do cliente: FABRICIA DE CASTRO
Informe a idade: 23
Informe o sexo: F
FABRICIA DE CASTRO, você ganhou o desconto de 20%
Valor a pagar: 416.0

Informe o valor do produto: 830
Informe o nome do cliente: OSMAR SLVA
Informe a idade: 38
Informe o sexo: M
OSMAR SLVA, você ganhou apenas o desconto de 5%
Valor a pagar: 788.5

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

algoritmo "Ler o valor do produto, o valor do produto, o sexo..."
var
  valor: real
  nome, sexo: caractere
  idade: inteiro

inicio
  //  vamos ler o valor do produto
  escreva("Informe o valor do produto: ")
  leia(valor)

  // agora vamos ler o nome do cliente
  escreva("Informe o nome do cliente: ")
  leia(nome)

  // agora vamos ler a idade
  escreva("Informe a idade: ")
  leia(idade)

  // e finalmente vamos ler o sexo do cliente
  escreva("Informe o sexo: ")
  leia(sexo)

  // vamos verificar se o cliente faz jus ao desconto
  // de 20%
  se ((idade >= 18) e (idade <= 35) e (sexo = "F")) entao
    valor <- valor - (valor * (20 / 100))
    escreval(nome, ", você ganhou o desconto de 20%")
    escreval("Valor a pagar: ", valor)
  senao
    valor <- valor - (valor * (5 / 100))
    escreval(nome, ", você ganhou apenas o desconto de 5%")
    escreval("Valor a pagar: ", valor)
  fimse
  
fimalgoritmo

Informe o ano: 2024
O ano informado é bissexto.

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

algoritmo "Como testar se um ano é bissexto em VisuAlg"

var
  // variáveis usadas na resolução do problema
  ano: inteiro

inicio
  // vamos solicitar que o usuário informe um ano
  escreva("Informe o ano: ")
  leia(ano)

  // vamos verificar se o ano informado é bissexto
  se (((ano mod 4 = 0) e (ano mod 100 <> 0)) ou (ano mod 400 = 0)) entao
    escreva("O ano informado é bissexto.")
  senao
    escreva("O ano informado não é bissexto.")
  fimse

fimalgoritmo