Adivinhe o número mágico: 100
Tente um número menor.

Adivinhe o número mágico: 50
Tente um número maior.

Adivinhe o número mágico: 60
Tente um número maior.

Adivinhe o número mágico: 80
Tente um número maior.

Adivinhe o número mágico: 90
Tente um número maior.

Adivinhe o número mágico: 95
Tente um número menor.

Adivinhe o número mágico: 94
Tente um número menor.

Adivinhe o número mágico: 93
Tente um número menor.

Adivinhe o número mágico: 92
Você acertou o número em 9 tentativas.
Classificação: Normal

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

algoritmo "Desafio do número mágico em VisuAlg"

var
  // variáveis usadas na resolução do problema
  numero_magico, palpite, tentativas: inteiro
  acertou: logico

inicio
  // inicializa as variáveis
  tentativas <- 0
  acertou <- falso

  // vamos sortear o número entre 0 e 500
  numero_magico <- RandI(501)

  // um laço que repete enquanto o usuário não
  // acertar o número mágico
  enquanto nao acertou faca
    escreva("Adivinhe o número mágico: ")
    leia(palpite)

    // registra essa tentativa
    tentativas <- tentativas + 1

    // o usuário acertou o número mágico?
    se palpite = numero_magico entao
      escreval("Você acertou o número em ", tentativas, " tentativas.")

      // mostra a classificação do usuário
      se tentativas <= 3 entao
        escreval("Classificação: Muito Sortudo")
      senao
        se (tentativas >= 4) e (tentativas <= 6) entao
          escreval("Classificação: Sortudo")
        senao
          se (tentativas >= 7) e (tentativas <= 10) entao
            escreval("Classificação: Normal")
          senao
            escreval("Classificação: Tente Novamente")
          fimse
        fimse
      fimse

      // sai do laço
      acertou <- verdadeiro
    senao
      // indica se o palpite é maior ou menor
      se palpite < numero_magico entao
        escreval("Tente um número maior.")
        escreval()
      senao
        escreval("Tente um número menor.")
        escreval()
      fimse
    fimse
  fimenquanto

fimalgoritmo

Informe um caractere: A
Você informou o caractere: A
O código ASCII correspondente é: 65

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

algoritmo "Como retornar código ASCII em VisuAlg"
var
  // variáveis usadas na resolução do problema
  ch: caractere
  codigo: inteiro

inicio
  // vamos pedir para o usuário informar uma letra, símbolo ou pontuação
  escreva("Informe um caractere: ")
  leia(ch)

  // agora vamos obter o código ASCII correspondente
  codigo <- Asc(ch)

  // e mostramos o resultado
  escreval("Você informou o caractere: ", ch)
  escreval("O código ASCII correspondente é: ", codigo)

fimalgoritmo

Informe o valor do carro sem desconto: 25000
Informe o ano do carro: 2010
Desconto concedido: 1750
Valor do carro com desconto: 23250
Deseja adicionar mais carros? [S, N]: S

Informe o valor do carro sem desconto: 30500
Informe o ano do carro: 1985
Desconto concedido: 3660
Valor do carro com desconto: 26840
Deseja adicionar mais carros? [S, N]: S

Informe o valor do carro sem desconto: 16800
Informe o ano do carro: 1990
Desconto concedido: 2016
Valor do carro com desconto: 14784
Deseja adicionar mais carros? [S, N]: N

Total de carros com ano até 2000: 2
Total geral a pagar: 64874

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

algoritmo "Cálculo de desconto nos preços de vários veículos"

var
  // variáveis usadas na resolução do problema
  valor_carro, valor_desconto, valor_carro_desconto: real
  total_geral: real
  ano: inteiro
  total_carros_ano_2000: inteiro
  resposta: caractere

inicio
  // vamos inicializar os valores de algumas variáveis
  total_geral <- 0
  total_carros_ano_2000 <- 0

  // repete até que o usuário informe o valor "N"
  repita
    // vamos ler o valor do carro sem desconto
    escreva("Informe o valor do carro sem desconto: ")
    leia(valor_carro)

    // vamos ler o ano do carro
    escreva("Informe o ano do carro: ")
    leia(ano)

    // o ano é menor ou igual a 2000
    se ano <= 2000 entao
      valor_desconto <- valor_carro * (12.0 / 100.0)
      // vamos somar mais este carro
      total_carros_ano_2000 <- total_carros_ano_2000 + 1
    senao
      valor_desconto <- valor_carro * (7.0 / 100.0)
    fimse

    // calculamos o valor do carro com o desconto
    valor_carro_desconto <- valor_carro - valor_desconto
    escreval("Desconto concedido: ", valor_desconto)
    escreval("Valor do carro com desconto: ", valor_carro_desconto)

    // somamos mais este valor ao total geral
    total_geral <- total_geral + valor_carro_desconto

    // perguntamos se o usuário deseja adicionar mais carros
    escreva("Deseja adicionar mais carros? [S, N]: ")
    leia(resposta)

    // adiciona uma quebra de linha
    escreval()
  ate resposta = "N"

  // mostramos os resultados
  escreval("Total de carros com ano até 2000: ", total_carros_ano_2000)
  escreval("Total geral a pagar: ", total_geral)

fimalgoritmo

50 primeiros números primos:

     2     3     5     7    11    13    17    19    23    29
    31    37    41    43    47    53    59    61    67    71
    73    79    83    89    97   101   103   107   109   113
   127   131   137   139   149   151   157   163   167   173
   179   181   191   193   197   199   211   223   227   229

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

algoritmo "Como exibir os N primeiros números primos em VisuAlg"

var
  // variáveis usadas na resolução do problema
  quantidade, contador, numero, j: inteiro
  primo: logico

inicio
  quantidade <- 50 // quantidade de números primos
  contador <- 0 // quantidade de números primos encontrados
  numero <- 0 // inteiro inicial

  // Lembre-se! O número 1 não é primo
  escreval(quantidade, " primeiros numeros primos:")
  escreval()

  // laço while será executado até encontrar os 50 primeiros números primos
  enquanto contador < quantidade faca
    primo <- verdadeiro

    // se o valor de i for 7, a variável j do laço contará
    // de 2 até 7 / 2 (divisão inteira), ou seja, 3. Se o
    // módulo de 7 por qualquer um dos valores neste intervalo
    // for igual a 0, então o número não é primo
    para j de 2 ate Int(numero / 2) faca
      se numero mod j = 0 entao
        primo <- falso // não é primo
        interrompa
      fimse
    fimpara

    se ((primo = verdadeiro) e (numero > 1)) entao
      escreva(numero:6)
      contador <- contador + 1 // encontramos um número primo

      se contador mod 10 = 0 entao
        escreval()
      fimse
    fimse

    numero <- numero + 1
  fimenquanto

fimalgoritmo