Informe o salário: 1350
Informe o valor do empréstimo: 6000
Informe a quantidade de parcelas: 12
O valor das parcelas do empréstimo é: 500.0
Empréstimo não pode ser concedido

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

algoritmo "Como testar aprovação de empréstimo em VisuAlg"

var
  // variáveis usadas na resolução do problema
  salario, emprestimo, valor_parcela: real
  quant_prestacoes: inteiro

inicio
  // vamos ler os dados
  escreva("Informe o salário: ")
  leia(salario)
  escreva("Informe o valor do empréstimo: ")
  leia(emprestimo)
  escreva("Informe a quantidade de parcelas: ")
  leia(quant_prestacoes)

  // vamos calcular e mostrar o valor da parcela do empréstimo
  valor_parcela <- emprestimo / quant_prestacoes
  escreval("O valor das parcelas do empréstimo é: ", valor_parcela)

  // o empréstimo pode ser concedido?
  se valor_parcela > (salario * (20.0 / 100.0)) entao
    escreval("Empréstimo não pode ser concedido")
  senao
    escreval("Empréstimo pode ser concedido")
  fimse

fimalgoritmo

Informe o primeiro número: 34
Informe o segundo número: 83
Informe o terceiro número: 72
O segundo número é o maior

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

Algoritmo "Um programa que lê três números inteiros e mostra o maior"

Var
  // variáveis usadas na resolução do problema
  num1, num2, num3: inteiro

Inicio
  // vamos solicitar os três números inteiros
  escreva("Informe o primeiro número: ")
  leia(num1)
  escreva("Informe o segundo número: ")
  leia(num2)
  escreva("Informe o terceiro número: ")
  leia(num3)

  // o primeiro número é o maior?
  se (num1 > num2) e (num1 > num3) entao
    escreva("O primeiro número é o maior")
  senao
    // o segundo número é o maior?
    se (num2 > num1) e (num2 > num3) entao
      escreva("O segundo número é o maior")
    senao
      // o terceiro número é o maior?
      se (num3 > num1) e (num3 > num2) entao
        escreva("O terceiro número é o maior")
      senao
        // os números não são diferentes
        escreva("Os três números não são diferentes")
      fimse
    fimse
  fimse

Fimalgoritmo

50 primeiros números primos:

     2     3     5     7    11    13    17    19    23    29
    31    37    41    43    47    53    59    61    67    71
    73    79    83    89    97   101   103   107   109   113
   127   131   137   139   149   151   157   163   167   173
   179   181   191   193   197   199   211   223   227   229

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

algoritmo "Como exibir os N primeiros números primos em VisuAlg"

var
  // variáveis usadas na resolução do problema
  quantidade, contador, numero, j: inteiro
  primo: logico

inicio
  quantidade <- 50 // quantidade de números primos
  contador <- 0 // quantidade de números primos encontrados
  numero <- 0 // inteiro inicial

  // Lembre-se! O número 1 não é primo
  escreval(quantidade, " primeiros numeros primos:")
  escreval()

  // laço while será executado até encontrar os 50 primeiros números primos
  enquanto contador < quantidade faca
    primo <- verdadeiro

    // se o valor de i for 7, a variável j do laço contará
    // de 2 até 7 / 2 (divisão inteira), ou seja, 3. Se o
    // módulo de 7 por qualquer um dos valores neste intervalo
    // for igual a 0, então o número não é primo
    para j de 2 ate Int(numero / 2) faca
      se numero mod j = 0 entao
        primo <- falso // não é primo
        interrompa
      fimse
    fimpara

    se ((primo = verdadeiro) e (numero > 1)) entao
      escreva(numero:6)
      contador <- contador + 1 // encontramos um número primo

      se contador mod 10 = 0 entao
        escreval()
      fimse
    fimse

    numero <- numero + 1
  fimenquanto

fimalgoritmo

// declara um vetor de 10 inteiros
valores: vetor[1..10] de inteiro

Informe um valor: 4
O valor foi encontrado: 3 vezes

Informe um valor: 8
O valor foi encontrado: 1 vezes

Informe um valor: 3
O valor foi encontrado: 0 vezes

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

algoritmo "Contar quantas vezes um elemento repete em um vetor"

var
  // variáveis usadas na resolução do problema
  valores: vetor[1..10] de inteiro
  pesquisa, repeticoes, i: inteiro

inicio
  // inicializa um vetor de 10 inteiros
  valores[1] <- 4
  valores[2] <- 21
  valores[3] <- 9
  valores[4] <- 8
  valores[5] <- 12
  valores[6] <- 21
  valores[7] <- 4
  valores[8] <- 4
  valores[9] <- 1
  valores[10] <- 10

  // vamos ler um valor inteiro
  escreva("Informe um valor: ")
  leia(pesquisa)

  // vamos verificar quantas vezes o valor informado está
  // contido no vetor
  repeticoes <- 0
  para i de 1 ate 10 faca
    se valores[i] = pesquisa entao
      // encontrou? vamos contar esta ocorrência
      repeticoes <- repeticoes + 1
    fimse
  fimpara

  // vamos mostrar o resultado
  escreva("O valor foi encontrado: ", repeticoes, " vezes")

fimalgoritmo