Você está aqui: Portugol ::: Desafios e Lista de Exercícios Resolvidos ::: Arrays e Matrix (Vetores e Matrizes) |
Matriz Simétrica em Portugol - Um programa Portugol que testa se uma matriz quadrada é uma matriz simétrica - Desafio de Programação Resolvido em PortugolQuantidade de visualizações: 268 vezes |
Pergunta/Tarefa: Antes de fazermos a resolução deste exercício de matrizes em Portugol, é importante revermos alguns conceitos sobre a matriz simétrica. O que é uma matriz simétrica Uma matriz simétrica é toda matriz cuja matriz transposta é igual à própria matriz, ou seja, A = At. Para compreender o que é uma matriz simétrica, é importante revermos o que é uma matriz transposta. Matriz transposta: quando invertemos as linhas e colunas de uma matriz, ou seja, dada a matriz A, a matriz transposta de A, representada por At, terá em sua primeira coluna a primeira linha da matriz A; já a segunda coluna da matriz transposta será a segunda linha da matriz A, e assim sucessivamente. Veja a figura: ![]() Matriz simétrica: sabendo o que é uma matriz transposta, dada a matriz A, quando calculamos a matriz transposta de A e encontramos a própria matriz A, ou seja, A = At, então essa matriz é simétrica. Escreva um programa Portugol que declara uma matriz de inteiros de 3 linhas e 3 colunas e peça para o usuário informar os valores de cada elemento. Em seguida mostre a matriz informada e indique se a matriz é uma matriz simétrica ou não. Sua saída deverá ser parecida com: Elemento na linha 1 e coluna 1: 5 Elemento na linha 1 e coluna 2: 1 Elemento na linha 1 e coluna 3: 2 Elemento na linha 2 e coluna 1: 1 Elemento na linha 2 e coluna 2: 6 Elemento na linha 2 e coluna 3: 3 Elemento na linha 3 e coluna 1: 2 Elemento na linha 3 e coluna 2: 3 Elemento na linha 3 e coluna 3: 8 5 1 2 1 6 3 2 3 8 A matriz informada é uma matriz simétrica. Veja a resolução comentada deste exercício em Portugol Web Studio: ---------------------------------------------------------------------- Se precisar de ajuda com o código abaixo, pode me chamar no WhatsApp +55 (62) 98553-6711 (Osmar) ---------------------------------------------------------------------- // Matriz simétrica em Portugol programa { funcao inicio() { // variáveis usadas na resolução do problema inteiro n = 3 // ordem da matriz quadrada inteiro matriz[n][n] logico simetrica = verdadeiro // vamos pedir para o usuário informar os valores // dos elementos da matriz, uma linha de cada vez para (inteiro i = 0; i < n; i++) { para (inteiro j = 0; j < n; j++) { escreva("Linha ", (i + 1), " e coluna ", (j + 1), ": ") leia(matriz[i][j]) } } // agora verificamos se a matriz é simétrica para (inteiro i = 0; ((i < n) e simetrica); i++) { para (inteiro j = 0; ((j < n) e simetrica); j++) { // os elementos em posicoes simetricas sao iguais? se (matriz[i][j] != matriz[j][i]) { simetrica = falso } } } // vamos mostrar a matriz da forma que ela foi informada escreva("\nValores na matriz:\n\n") para (inteiro i = 0; i < n; i++) { para (inteiro j = 0; j < n; j++) { escreva(matriz[i][j], " ") } // passa para a próxima linha da matriz escreva("\n") } se (simetrica) { escreva("\nA matriz informada é uma matriz simétrica.") } senao { escreva("\nA matriz informada não é uma matriz simétrica.") } } } |
![]() |
Portugol ::: Desafios e Lista de Exercícios Resolvidos ::: Estruturas de Controle |
Exercício Resolvido de Portugol - Um programa que lê três números inteiros e mostra o maiorQuantidade de visualizações: 2789 vezes |
Pergunta/Tarefa: Faça um algoritmo em Portugol que solicita três números inteiros e mostra o maior deles. Exiba uma mensagem caso os três números não forem diferentes. Sua saída deverá ser parecida com: Informe o primeiro número: 5 Informe o segundo número: 8 Informe o terceiro número: 3 O segundo número é o maior Veja a resolução comentada deste exercício usando Portugol Webstudio: ---------------------------------------------------------------------- Se precisar de ajuda com o código abaixo, pode me chamar no WhatsApp +55 (62) 98553-6711 (Osmar) ---------------------------------------------------------------------- // Um programa que lê três números inteiros e mostra o maior programa { funcao inicio() { // variáveis usadas na resolução do problema inteiro num1, num2, num3 // vamos solicitar os três números inteiros escreva("Informe o primeiro número: ") leia(num1) escreva("Informe o segundo número: ") leia(num2) escreva("Informe o terceiro número: ") leia(num3) // o primeiro número é o maior? se (num1 > num2 e num1 > num3) { escreva("O primeiro número é o maior") } senao { // o segundo número é o maior? se (num2 > num1 e num2 > num3) { escreva("O segundo número é o maior") } senao{ // o terceiro número é o maior? se (num3 > num1 e num3 > num2) { escreva("O terceiro número é o maior") } // os número não são diferentes senao { escreva("Os três números não são diferentes") } } } } |
Portugol ::: Desafios e Lista de Exercícios Resolvidos ::: Portugol Básico |
Exercícios Resolvidos de Portugol - Escreva um programa Portugol para calcular e imprimir o número de lâmpadas necessáriasQuantidade de visualizações: 346 vezes |
Pergunta/Tarefa: Escreva um programa Portugol para calcular e imprimir o número de lâmpadas necessárias para iluminar um determinado cômodo de uma residência. Dados de entrada: a potência da lâmpada utilizada (em watts), as dimensões (largura e comprimento, em metros) do cômodo. Considere que a potência necessária é de 18 watts por metro quadrado. Sua saída deverá ser parecida com: Informe a potência da lâmpada (em watts): 100 Informe a largura do cômodo (em metros): 6 Informe o comprimento do cômodo (em metros): 4 Serão necessárias 4 lâmpadas. Veja a resolução completa para o exercício em Portugol, comentada linha a linha (na resolução eu usei o Portugol Webstudio): ---------------------------------------------------------------------- Se precisar de ajuda com o código abaixo, pode me chamar no WhatsApp +55 (62) 98553-6711 (Osmar) ---------------------------------------------------------------------- programa { // vamos incluir a biblioteca Tipos inclua biblioteca Tipos --> tp funcao inicio() { // variáveis usadas na resolução do problema real potencia_lampada, largura_comodo, comprimento_comodo real area_comodo, potencia_total inteiro quant_lampadas // vamos ler a potência da lâmpada escreva("Informe a potência da lâmpada (em watts): ") leia(potencia_lampada) // vamos ler a largura do cômodo escreva("Informe a largura do cômodo (em metros): ") leia(largura_comodo) // agora vamos ler o comprimento do cômodo escreva("Informe o comprimento do cômodo (em metros): ") leia(comprimento_comodo) // agora vamos calcular a área do cômodo area_comodo = largura_comodo * comprimento_comodo // calculamos a potência total necessária para iluminar // todo o cômodo potencia_total = area_comodo * 18 // e finalmente calculamos a quantidade de lâmpadas necessárias quant_lampadas = tp.real_para_inteiro(potencia_total / potencia_lampada) // será necessário no mínimo uma lâmpada se (quant_lampadas == 0) { quant_lampadas = quant_lampadas + 1 } // e mostramos o resultado escreva("Serão necessárias ", quant_lampadas, " lâmpadas.") } } |
Portugol ::: Dicas & Truques ::: Cadeias e Caracteres |
Como testar se uma sub-cadeia está contida em uma cadeia de caracteres em Portugol usando a função posicao_texto()Quantidade de visualizações: 85 vezes |
Nesta dica mostrarei como podemos verificar se uma substring está contida em uma string em Portugol. Para isso nós vamos usar a função posicao_texto() da biblioteca Texto. A função posicao_texto() pede a sub-cadeia a ser pesquisada, a cadeia na qual a pesquisa será feita e o índice do primeiro caractere a partir do qual a sub-string será pesquisada. Se a substring for encontrada, a função retorna a posição do primeiro caractere. Caso contrário o valor -1 será retornado. Veja o código completo para um programa Portugol no qual testamos se uma palavra está contida em uma frase: ---------------------------------------------------------------------- Se precisar de ajuda com o código abaixo, pode me chamar no WhatsApp +55 (62) 98553-6711 (Osmar) ---------------------------------------------------------------------- programa { // vamos importar a biblioteca Texto inclua biblioteca Texto --> tx funcao inicio() { // vamos criar uma frase cadeia frase = "Gosto de programar em Portugol" // vamos criar uma sub-cadeia cadeia palavra = "Portugol" // vamos verificar se a sub-cadeia está contida na cadeia se (tx.posicao_texto(palavra, frase, 0) != -1) { escreva("A substring está contida na string") } senao { escreva("A substring não está contida na string") } } } Ao executar este código Portugol nós teremos o seguinte resultado: A substring está contida na string. |
Portugol ::: Desafios e Lista de Exercícios Resolvidos ::: Laços |
Exercícios Resolvidos de Portugol - A concessionária de veículos "CARANGO VELHO" está vendendo os seus veículos com descontos. Faça um algoritmo PortugolQuantidade de visualizações: 585 vezes |
Pergunta/Tarefa: A concessionária de veículos "CARANGO VELHO" está vendendo os seus veículos com descontos. Faça um algoritmo Portugol que calcule e exiba o valor do desconto e o valor a ser pago pelo cliente de vários carros. O desconto deverá ser calculado de acordo com o ano do veículo. Até o ano 2000 o desconto é 12%, e acima de 2000 o desconto é de 7%. Seu código deverá solicitar o valor do carro e o seu ano e aplicar o desconto correspondente. Além disso o sistema deverá perguntar se deseja continuar calculando descontos até que a resposta seja: "(N) Não". Informar o total de carros com ano até 2000 e o total geral a ser pago pelo cliente. Sua saída deve ser parecida com: Informe o valor do carro sem desconto: 25000 Informe o ano do carro: 2010 Desconto concedido: 1750 Valor do carro com desconto: 23250 Deseja adicionar mais carros? [S, N]: S Informe o valor do carro sem desconto: 30500 Informe o ano do carro: 1985 Desconto concedido: 3660 Valor do carro com desconto: 26840 Deseja adicionar mais carros? [S, N]: S Informe o valor do carro sem desconto: 16800 Informe o ano do carro: 1990 Desconto concedido: 2016 Valor do carro com desconto: 14784 Deseja adicionar mais carros? [S, N]: N Total de carros com ano até 2000: 2 Total geral a pagar: 64874 Veja a resolução comentada deste exercício usando Portugol Webstudio: ---------------------------------------------------------------------- Se precisar de ajuda com o código abaixo, pode me chamar no WhatsApp +55 (62) 98553-6711 (Osmar) ---------------------------------------------------------------------- programa { funcao inicio() { // variáveis usadas na resolução do problema real valor_carro, valor_desconto, valor_carro_desconto real total_geral inteiro ano inteiro total_carros_ano_2000 caracter resposta // vamos inicializar os valores de algumas variáveis total_geral = 0 total_carros_ano_2000 = 0 // repete até que o usuário informe o valor "N" faca { // vamos ler o valor do carro sem desconto escreva("\nInforme o valor do carro sem desconto: ") leia(valor_carro) // vamos ler o ano do carro escreva("Informe o ano do carro: ") leia(ano) // o ano é menor ou igual a 2000 se (ano <= 2000) { valor_desconto = valor_carro * (12.0 / 100.0) // vamos somar mais este carro total_carros_ano_2000 = total_carros_ano_2000 + 1 } senao { valor_desconto = valor_carro * (7.0 / 100.0) } // calculamos o valor do carro com o desconto valor_carro_desconto = valor_carro - valor_desconto escreva("Desconto concedido: ", valor_desconto) escreva("\nValor do carro com desconto: ", valor_carro_desconto) // somamos mais este valor ao total geral total_geral = total_geral + valor_carro_desconto // perguntamos se o usuário deseja adicionar mais carros escreva("\nDeseja adicionar mais carros? [S, N]: ") leia(resposta) } enquanto((resposta != 'N') e (resposta != 'n')) // mostramos os resultados escreva("\nTotal de carros com ano até 2000: ", total_carros_ano_2000) escreva("\nTotal geral a pagar: ", total_geral) } } |
Portugol ::: Dicas & Truques ::: Cadeias e Caracteres |
Como acessar os caracteres individuais de uma palavra ou frase em Portugol usando a função obter_caracter() da biblioteca TextoQuantidade de visualizações: 89 vezes |
Em algumas situações nós precisamos acessar os caracteres individuais de uma palavra ou frase no Portugol Studio ou Portugol Web Studio. Para isso nós podemos usar a função obter_caracter() da biblioteca Texto. Esta função pede, como primeiro argumento, a palavra ou frase a partir da qual o caractere será extraído e, como segundo argumento, o índice do caractere (sempre começando em 0 para o primeiro caractere). Veja um programa Portugol completo no qual obtemos o primeiro caractere de uma palavra: ---------------------------------------------------------------------- Se precisar de ajuda com o código abaixo, pode me chamar no WhatsApp +55 (62) 98553-6711 (Osmar) ---------------------------------------------------------------------- programa { // vamos importar a biblioteca Texto inclua biblioteca Texto --> tx funcao inicio() { cadeia palavra = "PORTUGOL" caracter letra = tx.obter_caracter(palavra, 0) escreva("A letra retornada é: ", letra) } } Ao executar este código Portugol nós teremos o seguinte resultado: A letra retornada é: P Veja agora como podemos usar o laço PARA para percorrer e exibir todos os caracteres individuais da palavra ou frase: ---------------------------------------------------------------------- Se precisar de ajuda com o código abaixo, pode me chamar no WhatsApp +55 (62) 98553-6711 (Osmar) ---------------------------------------------------------------------- programa { // vamos importar a biblioteca Texto inclua biblioteca Texto --> tx funcao inicio() { cadeia palavra = "PORTUGOL" para (inteiro i = 0; i <= tx.numero_caracteres(palavra) - 1; i++) { caracter letra = tx.obter_caracter(palavra, i) escreva("A letra é: ", letra, "\n") } } } Ao executar o código novamente nós teremos o seguinte resultado: A letra é: P A letra é: O A letra é: R A letra é: T A letra é: U A letra é: G A letra é: O A letra é: L |
Desafios, Exercícios e Algoritmos Resolvidos de Portugol |
Veja mais Dicas e truques de Portugol |
Dicas e truques de outras linguagens |
C++ - C++ Windows API GUI - Como criar sua primeira aplicação de interface gráfica usando C++ e WinAPI |
Quem Somos |
![]() Entre em contato comigo para, juntos, vermos em que posso contribuir para resolver ou agilizar o desenvolvimento de seus códigos.
|
![]() Não basta ter um site. É necessário ter um site que é localizado e converte usuários em clientes. Se sua página não faz isso, Fale comigo e vamos fazer uma analise e conseguir resultados mais satisfatórios..
|
Linguagens Mais Populares |
1º lugar: Java |
Códigos Fonte |
![]() Diga adeus às planilhas do Excel e tenha 100% de controle sobre suas contas a pagar e a receber, gestão de receitas e despesas, cadastro de clientes e fornecedores com fotos e histórico de atendimentos. Código fonte completo e funcional, com instruções para instalação e configuração do banco de dados MySQL. Fácil de modificar e adicionar novas funcionalidades. Clique aqui e saiba mais |
![]() Tenha o seu próprio sistema de controle de estoque web. com cadastro de produtos, categorias, fornecedores, entradas e saídas de produtos, com relatórios por data, margem de lucro e muito mais. Código simples e fácil de modificar. Acompanha instruções para instalação e criação do banco de dados MySQL. Clique aqui e saiba mais |