 |
|
Você está aqui: VisuAlg ::: Desafios e Lista de Exercícios Resolvidos ::: Arrays e Matrix (Vetores e Matrizes) |
Escreva um programa para informar o maior elemento de um vetor de 5 posições do tipo inteiro - Exercícios Resolvidos de VisuAlgQuantidade de visualizações: 729 vezes |
|
Pergunta/Tarefa: Escreva um programa para informar o maior elemento de um vetor de 5 posições do tipo inteiro. Esse programa deve possuir uma função para verificar o maior número desse vetor. Além disso, seu código deverá pedir para o usuário informar os valores do vetor. Sua saída deverá ser parecida com: Informe o valor do 1.o elemento: 4 Informe o valor do 2.o elemento: 12 Informe o valor do 3.o elemento: 8 Informe o valor do 4.o elemento: 4 Informe o valor do 5.o elemento: 11 O maior valor no vetor é: 12 Veja a resolução deste exercício em VisuAlg: ----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------
algoritmo "Ler um vetor de 5 inteiros e indicar o maior elemento"
var
// vamos declarar e construir um vetor de 5 inteiros
numeros: vetor[1..5] de inteiro
maior, i: inteiro
// função que retorna o maior valor no vetor. Note que o VisuAlg
// não permite a passagem de um vetor ou matriz para uma função. Por
// isso temos que declarar o vetor ou matriz no escopo global
funcao maior_valor(): inteiro
var
maior, i: inteiro
inicio
// vamos assumir que o maior valor é o primeiro elemento do vetor
maior <- numeros[1];
// agora vamos varrer o vetor e verificar se existe elemento com
// um valor maior do que aquele que já temos
para i de 1 ate 5 faca
se numeros[i] > maior entao
maior <- numeros[i]
fimse
fimpara
// retorna o maior valor encontrado
retorne maior
fimfuncao
// função principal do programa
inicio
// vamos pedir para o usuário informar os valores dos elementos
para i de 1 ate 5 faca
escreva("Informe o valor do ", i, ".o elemento: ")
leia(numeros[i])
fimpara
// agora vamos obter o maior valor
maior <- maior_valor()
escreva("O maior valor no vetor é: ", maior)
fimalgoritmo
|
 Link para compartilhar na Internet ou com seus amigos: |
VisuAlg ::: Dicas & Truques ::: Matemática e Estatística |
Como resolver uma equação do segundo grau em VisuAlg - Como calcular Bhaskara em VisuAlgQuantidade de visualizações: 1557 vezes |
|
Como resolver uma equação do 2º grau usando VisuAlg Nesta dica mostrarei como encontrar as raízes de uma equação quadrática, ou seja, uma equação do 2º usando um algoritmo escrito na ferramenta VisuAlg, uma das preferidas para o aprendizado de algoritmos e lógica de programação. Definimos como equação do 2º grau ou equações quadráticas qualquer equação do tipo ax² + bx + c = 0 em que a, b e c são números reais e a ≠ 0. Ela recebe esse nome porque, no primeiro membro da igualdade, há um polinômio de grau dois com uma única incógnita. Note que, dos coeficientes a, b e c, somente o a é diferente de zero, pois, caso ele fosse igual a zero, o termo ax² seria igual a zero, logo a equação se tornaria uma equação do primeiro grau: bx + c = 0. Independentemente da ordem da equação, o coeficiente a sempre acompanha o termo x², o coeficiente b sempre acompanha o termo x, e o coeficiente c é sempre o termo independente. Como resolver uma equação do 2º grau Conhecemos como soluções ou raízes da equação ax² + bx + c = 0 os valores de x que fazem com que essa equação seja verdadeira. Uma equação do 2º grau pode ter no máximo dois números reais que sejam raízes dela. Para resolver equações do 2º grau completas, existem dois métodos mais comuns: a) Fórmula de Bhaskara; b) Soma e produto. O primeiro método é bastante mecânico, o que faz com que muitos o prefiram. Já para utilizar o segundo, é necessário o conhecimento de múltiplos e divisores. Além disso, quando as soluções da equação são números quebrados, soma e produto não é uma alternativa boa. Como resolver uma equação do 2º grau usando Bhaskara Como nosso algoritmo VisuAlg vai resolver a equação quadrática usando a Fórmula de Bhaskara, o primeiro passo é encontrar o determinante. Veja: \[\Delta =b^2-4ac\] Nem sempre a equação possui solução real. O valor do determinante é que nos indica isso, existindo três possibilidades: a) Se determinante > 0, então a equação possui duas soluções reais. b) Se determinante = 0, então a equação possui uma única solução real. c) Se determinante < 0, então a equação não possui solução real. Encontrado o determinante, só precisamos substituir os valores, incluindo o determinante, na Fórmula de Bhaskara: \[x = \dfrac{- b\pm\sqrt{b^2- 4ac}}{2a}\] Vamos agora ao código VisuAlg. Nossa aplicação vai pedir para o usuário informar os valores dos três coeficientes a, b e c e, em seguida, vai apresentar as raizes da equação: ----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------
Algoritmo "Como resolver uma equação do 2º grau usando VisuAlg"
Var
// variáveis usadas na resolução do problema
// os coeficientes
a, b, c: real
// as duas raizes, a imaginaria e o discriminante
raiz1, raiz2, imaginaria, discriminante: real
Inicio
// vamos pedir para o usuário informar os valores dos coeficientes
escreva("Valor do coeficiente a: ")
leia(a)
escreva("Valor do coeficiente b: ")
leia(b)
escreva("Valor do coeficiente c: ")
leia(c)
// vamos calcular o discriminante
discriminante <- (b * b) - (4 * a * c)
// a equação possui duas soluções reais?
se discriminante > 0 então
raiz1 <- (-b + raizq(discriminante)) / (2 * a)
raiz2 <- (-b - raizq(discriminante)) / (2 * a)
escreva("Duas raizes: x1 = ", raiz1, " e x2 = ", raiz2)
senão
// a equação possui uma única solução real?
se discriminante = 0 então
raiz1 <- -b / (2 * a)
raiz2 <- -b / (2 * a)
escreva("Duas raizes iguais: x1 = ", raiz1, " e x2 = ", raiz2)
// a equação não possui solução real?
senão
raiz1 <- -b / (2 * a)
raiz2 <- -b / (2 * a)
imaginaria <- raizq(-discriminante) / (2 * a)
escreva("Existem duas raízes complexas: ")
escreva("x1 = ", raiz1, " + " ,imaginaria, " e x2 = ", raiz2, " - ", imaginaria)
fimse
fimse
Fimalgoritmo
Ao executar este código VisuAlg nós teremos o seguinte resultado: Valor do coeficiente a: 1 Valor do coeficiente b: 2 Valor do coeficiente c: -3 Existem duas raizes: x1 = 1.0 e x2 = -3.0 |
VisuAlg ::: Dicas & Truques ::: Matemática e Estatística |
Como calcular porcentagem em VisuAlg - Como efetuar cálculos de porcentagem em VisuAlgQuantidade de visualizações: 2104 vezes |
|
Cálculos de porcentagens estão presentes em boa parte das aplicações que desenvolvemos. Porém, há momentos em que a mente trava e não conseguimos lembrar com clareza como estes cálculos são feitos, principalmente em VisuAlg. Esta anotação tem o objetivo de ser uma fonte de pesquisa para os momentos em que suas habilidades matemáticas insistirem em continuar ocultas. Ex: 1 - Suponhamos que um produto que custe R$ 178,00 sofra um acréscimo de 15%. Qual o valor final do produto? Veja o código em VisuAlg: ----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------
algoritmo "Algoritmo que calcula porcentagem"
var
// variáveis usadas na resolução do problema
valor, percentual, valor_final: real
inicio
valor <- 178.00 // valor original
percentual <- 15.0 / 100.0 // 15%
valor_final <- valor + (percentual * valor)
// mostra o resultado
escreva("O valor final do produto é: ", valor_final)
// O resultado será 204,70
fimalgoritmo
Ex: 2 - Um produto, cujo valor original era de R$ 250,00, teve um desconto de 8%. Qual foi seu valor final? Veja o código em VisuAlg: ----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------
algoritmo "Algoritmo que calcula porcentagem"
var
// variáveis usadas na resolução do problema
valor, percentual, valor_final: real
inicio
valor <- 250.00; // valor original
percentual <- 8.0 / 100.0 // 8%
valor_final <- valor - (percentual * valor)
// mostra o resultado
escreva("O valor final do produto é: ", valor_final)
// O resultado será 230,00
fimalgoritmo
Ex: 3 - Em um concurso de perguntas e respostas, um jovem acertou 72 das 90 perguntas apresentadas. Qual foi a porcentagem de acertos? E a porcentagem de erros? Veja o código em VisuAlg: ----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------
algoritmo "Algoritmo que calcula porcentagem"
var
// variáveis usadas na resolução do problema
perguntas, acertos: real
inicio
perguntas <- 90.0
acertos <- 72.0
// mostra a porcentagem de acertos
escreva("Porcentagem de acertos: ")
escreval(((acertos / perguntas) * 100), "%")
// mostra a porcentagem de erros
escreva("Porcentagem de erros: ")
escreval((((perguntas - acertos) / perguntas) * 100), "%")
// Os resultados serão 80% e 20%
fimalgoritmo
Ex: 4 - Um aparelho de CD foi adquirido por R$ 300,00 e revendido por R$ 340,00. Qual foi a porcentagem de lucro na transação? Veja o código em VisuAlg: ----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------
algoritmo "Algoritmo que calcula porcentagem"
var
// variáveis usadas na resolução do problema
valor_anterior, novo_valor, porcentagem_lucro: real
inicio
valor_anterior <- 300.0 // valor anterior
novo_valor <- 340.0 // valor novo
// calcula a porcentagem de lucro
// efetua o cálculo
porcentagem_lucro <- ((novo_valor * 100) / valor_anterior) - 100
escreva("A porcentagem de lucro foi de: ", porcentagem_lucro, "%")
// O resultado será 13,33
fimalgoritmo
Ex: 5 - Uma loja repassa 5% do lucro a seus vendedores. Se um produto custa R$ 70,00, qual o valor em reais repassado a um determinado vendedor? Veja o código em VisuAlg: ----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------
algoritmo "Algoritmo que calcula porcentagem"
var
// variáveis usadas na resolução do problema
valor, percentual, comissao: real
inicio
valor <- 70.0 // valor do produto
percentual <- 5.0 / 100.0 // 5%
// calcula a comissão
comissao <- percentual * valor
// mostra o resultado
escreva("O valor repassado ao vendedor é: ", comissao)
// O resultado será 3,5
fimalgoritmo
|
VisuAlg ::: Desafios e Lista de Exercícios Resolvidos ::: VisuAlg Básico |
Exercícios Resolvidos de VisuAlg - Escreva um programa VisuAlg para calcular e imprimir o número de lâmpadas necessáriasQuantidade de visualizações: 261 vezes |
|
Pergunta/Tarefa: Escreva um programa VisuAlg para calcular e imprimir o número de lâmpadas necessárias para iluminar um determinado cômodo de uma residência. Dados de entrada: a potência da lâmpada utilizada (em watts), as dimensões (largura e comprimento, em metros) do cômodo. Considere que a potência necessária é de 18 watts por metro quadrado. Sua saída deverá ser parecida com: Informe a potência da lâmpada (em watts): 100 Informe a largura do cômodo (em metros): 6 Informe o comprimento do cômodo (em metros): 4 Serão necessárias 4 lâmpadas. Veja a resolução completa para o exercício em VisuAlg, comentada linha a linha: ----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------
algoritmo "Como calcular o número de lâmpadas necessárias"
var
// variáveis usadas na resolução do problema
potencia_lampada, largura_comodo, comprimento_comodo: real
area_comodo, potencia_total: real
quant_lampadas: inteiro
inicio
// vamos ler a potência da lâmpada
escreva("Informe a potência da lâmpada (em watts): ")
leia(potencia_lampada)
// vamos ler a largura do cômodo
escreva("Informe a largura do cômodo (em metros): ")
leia(largura_comodo)
// agora vamos ler o comprimento do cômodo
escreva("Informe o comprimento do cômodo (em metros): ")
leia(comprimento_comodo)
// agora vamos calcular a área do cômodo
area_comodo <- largura_comodo * comprimento_comodo
// calculamos a potência total necessária para iluminar
// todo o cômodo
potencia_total <- area_comodo * 18
// e finalmente calculamos a quantidade de lâmpadas necessárias
quant_lampadas <- Int(potencia_total / potencia_lampada)
// será necessário no mínimo uma lâmpada
se quant_lampadas = 0 entao
quant_lampadas <- quant_lampadas + 1
fimse
// e mostramos o resultado
escreva("Serão necessárias ", quant_lampadas, " lâmpadas.")
fimalgoritmo
|
Mais Desafios de Programação e Exercícios e Algoritmos Resolvidos de VisuAlg |
Veja mais Dicas e truques de VisuAlg |
Dicas e truques de outras linguagens |
|
JavaScript - Como testar se uma string começa com uma determinada substring em JavaScript usando a função startsWith() |
Códigos Fonte |
 Software de Gestão Financeira com código fonte em PHP, MySQL, Bootstrap, jQuery - Inclui cadastro de clientes, fornecedores e ticket de atendimentoDiga adeus às planilhas do Excel e tenha 100% de controle sobre suas contas a pagar e a receber, gestão de receitas e despesas, cadastro de clientes e fornecedores com fotos e histórico de atendimentos. Código fonte completo e funcional, com instruções para instalação e configuração do banco de dados MySQL. Fácil de modificar e adicionar novas funcionalidades. Clique aqui e saiba mais |
 Controle de Estoque completo com código fonte em PHP, MySQL, Bootstrap, jQuery - 100% funcional e fácil de modificar e implementar novas funcionalidadesTenha o seu próprio sistema de controle de estoque web. com cadastro de produtos, categorias, fornecedores, entradas e saídas de produtos, com relatórios por data, margem de lucro e muito mais. Código simples e fácil de modificar. Acompanha instruções para instalação e criação do banco de dados MySQL. Clique aqui e saiba mais |
Linguagens Mais Populares |
|
1º lugar: Java |
