Informe o 1º valor: 5
Informe o 2º valor: 10
Informe o 3º valor: 3
Informe o 4º valor: 7
Informe o 5º valor: 5
Informe o 6º valor: 3
Informe o 7º valor: 19
Informe o 8º valor: 4
Informe o 9º valor: 12
Informe o 10º valor: 1
O maior valor lido foi:  19
O menor valor lido foi:  1

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

Algoritmo "Ler 10 números inteiros e informar o maior e o menor valor lido"

Var
  // variáveis usadas para resolver o problema
  valor: inteiro // guarda o valor lido
  maior, menor: inteiro // variáveis que guardarão o maior e o menor valor lido
  i: inteiro // para controlar o laço

Inicio
  // vamos pedir ao usuário que informe 10 valores inteiros
  para i de 1 até 10 faça
    escreva("Informe o", i, "º valor: ")
    leia(valor)
    
    // esta é a primeira iteração do laço? se for vamos assumir que o
    // maior e menor valor lido são o primeiro valor informado
    se i = 1 então
      maior <- valor
      menor <- valor
    senão
      // não é a primeira iteração
      // vamos verificar se é maior que o valor atual da variável maior
      se valor > maior então
        maior <- valor
      fimse
      // vamos verificar se é menor que o valor atual da variável menor
      se valor < menor então
        menor <- valor
      fimse
    fimse
    
  fimpara

  // vamos exibir o maior e o menor valor lido
  escreval("O maior valor lido foi: ", maior)
  escreval("O menor valor lido foi: ", menor)

Fimalgoritmo

Informe a quantidade de galinhas: 8
Informe a quantidade de vacas: 3
Informe a quantidade de porcos: 11
Quantidade de animais: 22
Quantidade de patas: 72

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

algoritmo "Desafio da fazenda em VisuAlg"

var
  // variáveis usadas na resolução do problema
  quant_galinhas, quant_vacas, quant_porcos: inteiro
  quant_total_animais, quant_patas_total: inteiro
  
inicio
  // vamos ler a quantidade de cada animal
  escreva("Informe a quantidade de galinhas: ")
  leia(quant_galinhas)
  escreva("Informe a quantidade de vacas: ")
  leia(quant_vacas)
  escreva("Informe a quantidade de porcos: ")
  leia(quant_porcos)

  // vamos calcular a quantidade de animais
  quant_total_animais <- quant_galinhas + quant_vacas + quant_porcos
  escreval("Quantidade de animais: ", quant_total_animais)

  // vamos calcular a quantidade de patas
  quant_patas_total <- quant_galinhas * 2
  quant_patas_total <- quant_patas_total + (quant_vacas * 4)
  quant_patas_total <- quant_patas_total + (quant_porcos * 4)
  escreval("Quantidade de patas: ", quant_patas_total)

fimalgoritmo

50 primeiros números primos:

     2     3     5     7    11    13    17    19    23    29
    31    37    41    43    47    53    59    61    67    71
    73    79    83    89    97   101   103   107   109   113
   127   131   137   139   149   151   157   163   167   173
   179   181   191   193   197   199   211   223   227   229

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

algoritmo "Como exibir os N primeiros números primos em VisuAlg"

var
  // variáveis usadas na resolução do problema
  quantidade, contador, numero, j: inteiro
  primo: logico

inicio
  quantidade <- 50 // quantidade de números primos
  contador <- 0 // quantidade de números primos encontrados
  numero <- 0 // inteiro inicial

  // Lembre-se! O número 1 não é primo
  escreval(quantidade, " primeiros numeros primos:")
  escreval()

  // laço while será executado até encontrar os 50 primeiros números primos
  enquanto contador < quantidade faca
    primo <- verdadeiro

    // se o valor de i for 7, a variável j do laço contará
    // de 2 até 7 / 2 (divisão inteira), ou seja, 3. Se o
    // módulo de 7 por qualquer um dos valores neste intervalo
    // for igual a 0, então o número não é primo
    para j de 2 ate Int(numero / 2) faca
      se numero mod j = 0 entao
        primo <- falso // não é primo
        interrompa
      fimse
    fimpara

    se ((primo = verdadeiro) e (numero > 1)) entao
      escreva(numero:6)
      contador <- contador + 1 // encontramos um número primo

      se contador mod 10 = 0 entao
        escreval()
      fimse
    fimse

    numero <- numero + 1
  fimenquanto

fimalgoritmo

Informe o ano: 2024
O ano informado é bissexto.

----------------------------------------------------------------------
Se precisar de ajuda com o código abaixo, pode me chamar
no WhatsApp +55 (62) 98553-6711 (Osmar)
----------------------------------------------------------------------

algoritmo "Como testar se um ano é bissexto em VisuAlg"

var
  // variáveis usadas na resolução do problema
  ano: inteiro

inicio
  // vamos solicitar que o usuário informe um ano
  escreva("Informe o ano: ")
  leia(ano)

  // vamos verificar se o ano informado é bissexto
  se (((ano mod 4 = 0) e (ano mod 100 <> 0)) ou (ano mod 400 = 0)) entao
    escreva("O ano informado é bissexto.")
  senao
    escreva("O ano informado não é bissexto.")
  fimse

fimalgoritmo